From f275790aec4a796ed969b099364abfdf25385967 Mon Sep 17 00:00:00 2001
From: Rangi <remy.oukaour+rangi42@gmail.com>
Date: Thu, 2 Jul 2020 23:30:21 -0400
Subject: Add subdirectories to engine/ similar to pokecrystal

---
 engine/battle/move_effects/paralyze.asm | 47 +++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 engine/battle/move_effects/paralyze.asm

(limited to 'engine/battle/move_effects/paralyze.asm')

diff --git a/engine/battle/move_effects/paralyze.asm b/engine/battle/move_effects/paralyze.asm
new file mode 100644
index 00000000..95979ae6
--- /dev/null
+++ b/engine/battle/move_effects/paralyze.asm
@@ -0,0 +1,47 @@
+ParalyzeEffect_:
+	ld hl, wEnemyMonStatus
+	ld de, wPlayerMoveType
+	ld a, [H_WHOSETURN]
+	and a
+	jp z, .next
+	ld hl, wBattleMonStatus
+	ld de, wEnemyMoveType
+.next
+	ld a, [hl]
+	and a ; does the target already have a status ailment?
+	jr nz, .didntAffect
+; check if the target is immune due to types
+	ld a, [de]
+	cp ELECTRIC
+	jr nz, .hitTest
+	ld b, h
+	ld c, l
+	inc bc
+	ld a, [bc]
+	cp GROUND
+	jr z, .doesntAffect
+	inc bc
+	ld a, [bc]
+	cp GROUND
+	jr z, .doesntAffect
+.hitTest
+	push hl
+	callab MoveHitTest
+	pop hl
+	ld a, [wMoveMissed]
+	and a
+	jr nz, .didntAffect
+	set PAR, [hl]
+	callab QuarterSpeedDueToParalysis
+	ld c, 30
+	call DelayFrames
+	callab PlayCurrentMoveAnimation
+	jpab PrintMayNotAttackText
+.didntAffect
+	ld c, 50
+	call DelayFrames
+	jpab PrintDidntAffectText
+.doesntAffect
+	ld c, 50
+	call DelayFrames
+	jpab PrintDoesntAffectText
-- 
cgit v1.3.1-sl0p