From f275790aec4a796ed969b099364abfdf25385967 Mon Sep 17 00:00:00 2001
From: Rangi <remy.oukaour+rangi42@gmail.com>
Date: Thu, 2 Jul 2020 23:30:21 -0400
Subject: Add subdirectories to engine/ similar to pokecrystal

---
 .../battle/move_effects/reflect_light_screen.asm   | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 engine/battle/move_effects/reflect_light_screen.asm

(limited to 'engine/battle/move_effects/reflect_light_screen.asm')

diff --git a/engine/battle/move_effects/reflect_light_screen.asm b/engine/battle/move_effects/reflect_light_screen.asm
new file mode 100644
index 00000000..2805a969
--- /dev/null
+++ b/engine/battle/move_effects/reflect_light_screen.asm
@@ -0,0 +1,45 @@
+ReflectLightScreenEffect_:
+	ld hl, wPlayerBattleStatus3
+	ld de, wPlayerMoveEffect
+	ld a, [H_WHOSETURN]
+	and a
+	jr z, .reflectLightScreenEffect
+	ld hl, wEnemyBattleStatus3
+	ld de, wEnemyMoveEffect
+.reflectLightScreenEffect
+	ld a, [de]
+	cp LIGHT_SCREEN_EFFECT
+	jr nz, .reflect
+	bit HAS_LIGHT_SCREEN_UP, [hl] ; is mon already protected by light screen?
+	jr nz, .moveFailed
+	set HAS_LIGHT_SCREEN_UP, [hl] ; mon is now protected by light screen
+	ld hl, LightScreenProtectedText
+	jr .playAnim
+.reflect
+	bit HAS_REFLECT_UP, [hl] ; is mon already protected by reflect?
+	jr nz, .moveFailed
+	set HAS_REFLECT_UP, [hl] ; mon is now protected by reflect
+	ld hl, ReflectGainedArmorText
+.playAnim
+	push hl
+	ld hl, PlayCurrentMoveAnimation
+	call BankswitchEtoF
+	pop hl
+	jp PrintText
+.moveFailed
+	ld c, 50
+	call DelayFrames
+	ld hl, PrintButItFailedText_
+	jp BankswitchEtoF
+
+LightScreenProtectedText:
+	TX_FAR _LightScreenProtectedText
+	db "@"
+
+ReflectGainedArmorText:
+	TX_FAR _ReflectGainedArmorText
+	db "@"
+
+BankswitchEtoF:
+	ld b, BANK(BattleCore)
+	jp Bankswitch
-- 
cgit v1.3.1-sl0p