Add macros, constants, and labels for map scripts and text (#367)

This introduces `def_script_pointers`, `def_text_pointers`, and `object_const_def` macros, and applies them to all maps. Most other map labels have also been identified.

1 files changed, 137 insertions, 135 deletions

diff --git a/scripts/Route22.asm b/scripts/Route22.asm
index 1b02752f..f692cb37 100644
--- a/scripts/Route22.asm
+++ b/scripts/Route22.asm
@@ -5,37 +5,38 @@ Route22_Script:
 	jp CallFunctionInTable
 
 Route22_ScriptPointers:
-	dw Route22Script0
-	dw Route22Script1
-	dw Route22Script2
-	dw Route22Script3
-	dw Route22Script4
-	dw Route22Script5
-	dw Route22Script6
-	dw Route22Script7
+	def_script_pointers
+	dw_const Route22DefaultScript,           SCRIPT_ROUTE22_DEFAULT
+	dw_const Route22Rival1StartBattleScript, SCRIPT_ROUTE22_RIVAL1_START_BATTLE
+	dw_const Route22Rival1AfterBattleScript, SCRIPT_ROUTE22_RIVAL1_AFTER_BATTLE
+	dw_const Route22Rival1ExitScript,        SCRIPT_ROUTE22_RIVAL1_EXIT
+	dw_const Route22Rival2StartBattleScript, SCRIPT_ROUTE22_RIVAL2_START_BATTLE
+	dw_const Route22Rival2AfterBattleScript, SCRIPT_ROUTE22_RIVAL2_AFTER_BATTLE
+	dw_const Route22Rival2ExitScript,        SCRIPT_ROUTE22_RIVAL2_EXIT
+	dw_const Route22NoopScript,              SCRIPT_ROUTE22_NOOP
 
-Route22Script_50ece:
-	xor a
+Route22SetDefaultScript:
+	xor a ; SCRIPT_ROUTE22_DEFAULT
 	ld [wJoyIgnore], a
 	ld [wRoute22CurScript], a
-Route22Script7:
+Route22NoopScript:
 	ret
 
-Route22Script_50ed6:
+Route22GetRivalTrainerNoByStarterScript:
 	ld a, [wRivalStarter]
 	ld b, a
-.asm_50eda
+.next_trainer_no
 	ld a, [hli]
 	cp b
-	jr z, .asm_50ee1
+	jr z, .got_trainer_no
 	inc hl
-	jr .asm_50eda
-.asm_50ee1
+	jr .next_trainer_no
+.got_trainer_no
 	ld a, [hl]
 	ld [wTrainerNo], a
 	ret
 
-Route22MoveRivalSprite:
+Route22MoveRivalRightScript:
 	ld de, Route22RivalMovementData
 	ld a, [wcf0d]
 	cp $1
@@ -54,7 +55,7 @@ Route22RivalMovementData:
 	db NPC_MOVEMENT_RIGHT
 	db -1 ; end
 
-Route22Script0:
+Route22DefaultScript:
 	CheckEvent EVENT_ROUTE22_RIVAL_WANTS_BATTLE
 	ret z
 	ld hl, .Route22RivalBattleCoords
@@ -64,14 +65,14 @@ Route22Script0:
 	ld [wcf0d], a
 	xor a
 	ldh [hJoyHeld], a
-	ld a, $f0
+	ld a, D_RIGHT | D_LEFT | D_UP | D_DOWN
 	ld [wJoyIgnore], a
 	ld a, PLAYER_DIR_LEFT
 	ld [wPlayerMovingDirection], a
 	CheckEvent EVENT_1ST_ROUTE22_RIVAL_BATTLE
-	jr nz, .firstRivalBattle
-	CheckEventReuseA EVENT_2ND_ROUTE22_RIVAL_BATTLE ; is this the rival at the end of the game?
-	jp nz, Route22Script_5104e
+	jr nz, Route22FirstRivalBattleScript
+	CheckEventReuseA EVENT_2ND_ROUTE22_RIVAL_BATTLE
+	jp nz, Route22SecondRivalBattleScript
 	ret
 
 .Route22RivalBattleCoords
@@ -79,92 +80,92 @@ Route22Script0:
 	dbmapcoord 29,  5
 	db -1 ; end
 
-.firstRivalBattle
-	ld a, $1
+Route22FirstRivalBattleScript:
+	ld a, ROUTE22_RIVAL1
 	ld [wEmotionBubbleSpriteIndex], a
 	xor a ; EXCLAMATION_BUBBLE
 	ld [wWhichEmotionBubble], a
 	predef EmotionBubble
 	ld a, [wWalkBikeSurfState]
 	and a
-	jr z, .asm_50f4e
+	jr z, .walking
 	ld a, SFX_STOP_ALL_MUSIC
 	ld [wNewSoundID], a
 	call PlaySound
-.asm_50f4e
+.walking
 	ld c, BANK(Music_MeetRival)
 	ld a, MUSIC_MEET_RIVAL
 	call PlayMusic
-	ld a, $1
+	ld a, ROUTE22_RIVAL1
 	ldh [hSpriteIndex], a
-	call Route22MoveRivalSprite
-	ld a, $1
+	call Route22MoveRivalRightScript
+	ld a, SCRIPT_ROUTE22_RIVAL1_START_BATTLE
 	ld [wRoute22CurScript], a
 	ret
 
-Route22Script1:
+Route22Rival1StartBattleScript:
 	ld a, [wd730]
 	bit 0, a
 	ret nz
 	ld a, [wcf0d]
 	cp $1
-	jr nz, .asm_50f78
+	jr nz, .set_rival_facing_right
 	ld a, PLAYER_DIR_DOWN
 	ld [wPlayerMovingDirection], a
 	ld a, SPRITE_FACING_UP
-	jr .asm_50f7a
-.asm_50f78
+	jr .set_rival_facing_direction
+.set_rival_facing_right
 	ld a, SPRITE_FACING_RIGHT
-.asm_50f7a
+.set_rival_facing_direction
 	ldh [hSpriteFacingDirection], a
-	ld a, $1
+	ld a, ROUTE22_RIVAL1
 	ldh [hSpriteIndex], a
 	call SetSpriteFacingDirectionAndDelay
 	xor a
 	ld [wJoyIgnore], a
-	ld a, $1
+	ld a, TEXT_ROUTE22_RIVAL1
 	ldh [hSpriteIndexOrTextID], a
 	call DisplayTextID
 	ld hl, wd72d
 	set 6, [hl]
 	set 7, [hl]
-	ld hl, Route22RivalDefeatedText1
-	ld de, Route22Text_511bc
+	ld hl, Route22Rival1DefeatedText
+	ld de, Route22Rival1VictoryText
 	call SaveEndBattleTextPointers
 	ld a, OPP_RIVAL1
 	ld [wCurOpponent], a
-	ld hl, StarterMons_50faf
-	call Route22Script_50ed6
-	ld a, $2
+	ld hl, .StarterTable
+	call Route22GetRivalTrainerNoByStarterScript
+	ld a, SCRIPT_ROUTE22_RIVAL1_AFTER_BATTLE
 	ld [wRoute22CurScript], a
 	ret
 
-StarterMons_50faf:
+.StarterTable:
 ; starter the rival picked, rival trainer number
 	db STARTER2, 4
 	db STARTER3, 5
 	db STARTER1, 6
 
-Route22Script2:
+Route22Rival1AfterBattleScript:
 	ld a, [wIsInBattle]
 	cp $ff
-	jp z, Route22Script_50ece
+	jp z, Route22SetDefaultScript
 	ld a, [wSpritePlayerStateData1FacingDirection]
 	and a ; cp SPRITE_FACING_DOWN
-	jr nz, .notDown
+	jr nz, .not_facing_down
 	ld a, SPRITE_FACING_UP
-	jr .done
-.notDown
+	jr .set_rival_facing
+.not_facing_down
 	ld a, SPRITE_FACING_RIGHT
-.done
+.set_rival_facing
 	ldh [hSpriteFacingDirection], a
-	ld a, $1
+	ld a, ROUTE22_RIVAL1
 	ldh [hSpriteIndex], a
 	call SetSpriteFacingDirectionAndDelay
-	ld a, $f0
+	ld a, D_RIGHT | D_LEFT | D_UP | D_DOWN
 	ld [wJoyIgnore], a
 	SetEvent EVENT_BEAT_ROUTE22_RIVAL_1ST_BATTLE
-	ld a, $1
+	ld a, TEXT_ROUTE22_RIVAL1
 	ldh [hSpriteIndexOrTextID], a
 	call DisplayTextID
 	ld a, SFX_STOP_ALL_MUSIC
@@ -173,28 +174,28 @@ Route22Script2:
 	farcall Music_RivalAlternateStart
 	ld a, [wcf0d]
 	cp $1
-	jr nz, .asm_50fff
-	call Route22Script_51008
-	jr .asm_51002
-.asm_50fff
-	call Route22Script_5100d
-.asm_51002
-	ld a, $3
+	jr nz, .exit_movement_2
+	call .RivalExit1Script
+	jr .next_script
+.exit_movement_2
+	call .RivalExit2Script
+.next_script
+	ld a, SCRIPT_ROUTE22_RIVAL1_EXIT
 	ld [wRoute22CurScript], a
 	ret
 
-Route22Script_51008:
-	ld de, Route22RivalExitMovementData1
+.RivalExit1Script:
+	ld de, Route22Rival1ExitMovementData1
 	jr Route22MoveRival1
 
-Route22Script_5100d:
-	ld de, Route22RivalExitMovementData2
+.RivalExit2Script:
+	ld de, Route22Rival1ExitMovementData2
 Route22MoveRival1:
-	ld a, $1
+	ld a, ROUTE22_RIVAL1
 	ldh [hSpriteIndex], a
 	jp MoveSprite
 
-Route22RivalExitMovementData1:
+Route22Rival1ExitMovementData1:
 	db NPC_MOVEMENT_RIGHT
 	db NPC_MOVEMENT_RIGHT
 	db NPC_MOVEMENT_DOWN
@@ -204,7 +205,7 @@ Route22RivalExitMovementData1:
 	db NPC_MOVEMENT_DOWN
 	db -1 ; end
 
-Route22RivalExitMovementData2:
+Route22Rival1ExitMovementData2:
 	db NPC_MOVEMENT_UP
 	db NPC_MOVEMENT_RIGHT
 	db NPC_MOVEMENT_RIGHT
@@ -217,7 +218,7 @@ Route22RivalExitMovementData2:
 	db NPC_MOVEMENT_DOWN
 	db -1 ; end
 
-Route22Script3:
+Route22Rival1ExitScript:
 	ld a, [wd730]
 	bit 0, a
 	ret nz
@@ -228,102 +229,102 @@ Route22Script3:
 	predef HideObject
 	call PlayDefaultMusic
 	ResetEvents EVENT_1ST_ROUTE22_RIVAL_BATTLE, EVENT_ROUTE22_RIVAL_WANTS_BATTLE
-	ld a, $0
+	ld a, SCRIPT_ROUTE22_DEFAULT
 	ld [wRoute22CurScript], a
 	ret
 
-Route22Script_5104e:
-	ld a, $2
+Route22SecondRivalBattleScript:
+	ld a, ROUTE22_RIVAL2
 	ld [wEmotionBubbleSpriteIndex], a
 	xor a ; EXCLAMATION_BUBBLE
 	ld [wWhichEmotionBubble], a
 	predef EmotionBubble
 	ld a, [wWalkBikeSurfState]
 	and a
-	jr z, .skipYVisibilityTesta
+	jr z, .walking
 	ld a, SFX_STOP_ALL_MUSIC
 	ld [wNewSoundID], a
 	call PlaySound
-.skipYVisibilityTesta
+.walking
 	ld a, SFX_STOP_ALL_MUSIC
 	ld [wNewSoundID], a
 	call PlaySound
 	farcall Music_RivalAlternateTempo
-	ld a, $2
+	ld a, ROUTE22_RIVAL2
 	ldh [hSpriteIndex], a
-	call Route22MoveRivalSprite
-	ld a, $4
+	call Route22MoveRivalRightScript
+	ld a, SCRIPT_ROUTE22_RIVAL2_START_BATTLE
 	ld [wRoute22CurScript], a
 	ret
 
-Route22Script4:
+Route22Rival2StartBattleScript:
 	ld a, [wd730]
 	bit 0, a
 	ret nz
-	ld a, $2
+	ld a, ROUTE22_RIVAL2
 	ldh [hSpriteIndex], a
 	ld a, [wcf0d]
 	cp $1
-	jr nz, .asm_510a1
+	jr nz, .set_player_direction_left
 	ld a, PLAYER_DIR_DOWN
 	ld [wPlayerMovingDirection], a
 	ld a, SPRITE_FACING_UP
-	jr .asm_510a8
-.asm_510a1
+	jr .set_rival_facing_direction
+.set_player_direction_left
 	ld a, PLAYER_DIR_LEFT
 	ld [wPlayerMovingDirection], a
 	ld a, SPRITE_FACING_RIGHT
-.asm_510a8
+.set_rival_facing_direction
 	ldh [hSpriteFacingDirection], a
 	call SetSpriteFacingDirectionAndDelay
 	xor a
 	ld [wJoyIgnore], a
-	ld a, $2
+	ld a, TEXT_ROUTE22_RIVAL2
 	ldh [hSpriteIndexOrTextID], a
 	call DisplayTextID
 	ld hl, wd72d
 	set 6, [hl]
 	set 7, [hl]
-	ld hl, Route22RivalDefeatedText2
-	ld de, Route22Text_511d0
+	ld hl, Route22Rival2DefeatedText
+	ld de, Route22Rival2VictoryText
 	call SaveEndBattleTextPointers
 	ld a, OPP_RIVAL2
 	ld [wCurOpponent], a
-	ld hl, StarterMons_510d9
-	call Route22Script_50ed6
-	ld a, $5
+	ld hl, .StarterTable
+	call Route22GetRivalTrainerNoByStarterScript
+	ld a, SCRIPT_ROUTE22_RIVAL2_AFTER_BATTLE
 	ld [wRoute22CurScript], a
 	ret
 
-StarterMons_510d9:
+.StarterTable:
 	db STARTER2, 10
 	db STARTER3, 11
 	db STARTER1, 12
 
-Route22Script5:
+Route22Rival2AfterBattleScript:
 	ld a, [wIsInBattle]
 	cp $ff
-	jp z, Route22Script_50ece
-	ld a, $2
+	jp z, Route22SetDefaultScript
+	ld a, ROUTE22_RIVAL2
 	ldh [hSpriteIndex], a
 	ld a, [wcf0d]
 	cp $1
-	jr nz, .asm_510fb
+	jr nz, .set_player_direction_left
 	ld a, PLAYER_DIR_DOWN
 	ld [wPlayerMovingDirection], a
 	ld a, SPRITE_FACING_UP
-	jr .asm_51102
-.asm_510fb
+	jr .set_rival_facing_direction
+.set_player_direction_left
 	ld a, PLAYER_DIR_LEFT
 	ld [wPlayerMovingDirection], a
 	ld a, SPRITE_FACING_RIGHT
-.asm_51102
+.set_rival_facing_direction
 	ldh [hSpriteFacingDirection], a
 	call SetSpriteFacingDirectionAndDelay
-	ld a, $f0
+	ld a, D_RIGHT | D_LEFT | D_UP | D_DOWN
 	ld [wJoyIgnore], a
 	SetEvent EVENT_BEAT_ROUTE22_RIVAL_2ND_BATTLE
-	ld a, $2
+	ld a, TEXT_ROUTE22_RIVAL2
 	ldh [hSpriteIndexOrTextID], a
 	call DisplayTextID
 	ld a, SFX_STOP_ALL_MUSIC
@@ -332,36 +333,36 @@ Route22Script5:
 	farcall Music_RivalAlternateStartAndTempo
 	ld a, [wcf0d]
 	cp $1
-	jr nz, .asm_51134
-	call Route22Script_5113d
-	jr .asm_51137
-.asm_51134
-	call Route22Script_51142
-.asm_51137
-	ld a, $6
+	jr nz, .exit_movement_2
+	call .RivalExit1Script
+	jr .next_script
+.exit_movement_2
+	call .RivalExit2Script
+.next_script
+	ld a, SCRIPT_ROUTE22_RIVAL2_EXIT
 	ld [wRoute22CurScript], a
 	ret
 
-Route22Script_5113d:
-	ld de, MovementData_5114c
+.RivalExit1Script:
+	ld de, Route22Rival2ExitMovementData1
 	jr Route22MoveRival2
 
-Route22Script_51142:
-	ld de, MovementData_5114d
+.RivalExit2Script:
+	ld de, Route22Rival2ExitMovementData2
 Route22MoveRival2:
-	ld a, $2
+	ld a, ROUTE22_RIVAL2
 	ldh [hSpriteIndex], a
 	jp MoveSprite
 
-MovementData_5114c:
+Route22Rival2ExitMovementData1:
 	db NPC_MOVEMENT_LEFT
-MovementData_5114d:
+Route22Rival2ExitMovementData2:
 	db NPC_MOVEMENT_LEFT
 	db NPC_MOVEMENT_LEFT
 	db NPC_MOVEMENT_LEFT
 	db -1 ; end
 
-Route22Script6:
+Route22Rival2ExitScript:
 	ld a, [wd730]
 	bit 0, a
 	ret nz
@@ -372,39 +373,40 @@ Route22Script6:
 	predef HideObject
 	call PlayDefaultMusic
 	ResetEvents EVENT_2ND_ROUTE22_RIVAL_BATTLE, EVENT_ROUTE22_RIVAL_WANTS_BATTLE
-	ld a, $7
+	ld a, SCRIPT_ROUTE22_NOOP
 	ld [wRoute22CurScript], a
 	ret
 
 Route22_TextPointers:
-	dw Route22Text1
-	dw Route22Text2
-	dw Route22FrontGateText
+	def_text_pointers
+	dw_const Route22Rival1Text,            TEXT_ROUTE22_RIVAL1
+	dw_const Route22Rival2Text,            TEXT_ROUTE22_RIVAL2
+	dw_const Route22PokemonLeagueSignText, TEXT_ROUTE22_POKEMON_LEAGUE_SIGN
 
-Route22Text1:
+Route22Rival1Text:
 	text_asm
 	CheckEvent EVENT_BEAT_ROUTE22_RIVAL_1ST_BATTLE
-	jr z, .asm_5118b
+	jr z, .before_battle
 	ld hl, Route22RivalAfterBattleText1
 	call PrintText
-	jr .asm_51191
-.asm_5118b
+	jr .text_script_end
+.before_battle
 	ld hl, Route22RivalBeforeBattleText1
 	call PrintText
-.asm_51191
+.text_script_end
 	jp TextScriptEnd
 
-Route22Text2:
+Route22Rival2Text:
 	text_asm
 	CheckEvent EVENT_BEAT_ROUTE22_RIVAL_2ND_BATTLE
-	jr z, .asm_511a4
+	jr z, .before_battle
 	ld hl, Route22RivalAfterBattleText2
 	call PrintText
-	jr .asm_511aa
-.asm_511a4
+	jr .text_script_end
+.before_battle
 	ld hl, Route22RivalBeforeBattleText2
 	call PrintText
-.asm_511aa
+.text_script_end
 	jp TextScriptEnd
 
 Route22RivalBeforeBattleText1:
@@ -415,12 +417,12 @@ Route22RivalAfterBattleText1:
 	text_far _Route22RivalAfterBattleText1
 	text_end
 
-Route22RivalDefeatedText1:
-	text_far _Route22RivalDefeatedText1
+Route22Rival1DefeatedText:
+	text_far _Route22Rival1DefeatedText
 	text_end
 
-Route22Text_511bc:
-	text_far _Route22Text_511bc
+Route22Rival1VictoryText:
+	text_far _Route22Rival1VictoryText
 	text_end
 
 Route22RivalBeforeBattleText2:
@@ -431,14 +433,14 @@ Route22RivalAfterBattleText2:
 	text_far _Route22RivalAfterBattleText2
 	text_end
 
-Route22RivalDefeatedText2:
-	text_far _Route22RivalDefeatedText2
+Route22Rival2DefeatedText:
+	text_far _Route22Rival2DefeatedText
 	text_end
 
-Route22Text_511d0:
-	text_far _Route22Text_511d0
+Route22Rival2VictoryText:
+	text_far _Route22Rival2VictoryText
 	text_end
 
-Route22FrontGateText:
-	text_far _Route22FrontGateText
+Route22PokemonLeagueSignText:
+	text_far _Route22PokemonLeagueSignText
 	text_end