1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
HandleLedges::
ld a, [wMovementFlags]
bit BIT_LEDGE_OR_FISHING, a
ret nz
ld a, [wCurMapTileset]
and a ; OVERWORLD
ret nz
predef GetTileAndCoordsInFrontOfPlayer
ld a, [wSpritePlayerStateData1FacingDirection]
ld b, a
lda_coord 8, 9
ld c, a
ld a, [wTileInFrontOfPlayer]
ld d, a
ld hl, LedgeTiles
.loop
ld a, [hli]
cp $ff
ret z
cp b
jr nz, .nextLedgeTile1
ld a, [hli]
cp c
jr nz, .nextLedgeTile2
ld a, [hli]
cp d
jr nz, .nextLedgeTile3
ld a, [hl]
ld e, a
jr .foundMatch
.nextLedgeTile1
inc hl
.nextLedgeTile2
inc hl
.nextLedgeTile3
inc hl
jr .loop
.foundMatch
ldh a, [hJoyHeld]
and e
ret z
ld a, PAD_BUTTONS | PAD_CTRL_PAD
ld [wJoyIgnore], a
ld hl, wMovementFlags
set BIT_LEDGE_OR_FISHING, [hl]
call StartSimulatingJoypadStates
ld a, e
ld [wSimulatedJoypadStatesEnd], a
ld [wSimulatedJoypadStatesEnd + 1], a
ld a, $2
ld [wSimulatedJoypadStatesIndex], a
call LoadHoppingShadowOAM
ld a, SFX_LEDGE
call PlaySound
ret
INCLUDE "data/tilesets/ledge_tiles.asm"
LoadHoppingShadowOAM:
ld hl, vChars1 tile $7f
ld de, LedgeHoppingShadow
lb bc, BANK(LedgeHoppingShadow), (LedgeHoppingShadowEnd - LedgeHoppingShadow) / TILE_1BPP_SIZE
call CopyVideoDataDouble
ld hl, LedgeHoppingShadowOAM
ld de, wShadowOAMSprite36
ld bc, LedgeHoppingShadowOAMEnd - LedgeHoppingShadowOAM
call CopyData
ld a, $a0
ld [wShadowOAMSprite38YCoord], a
ld [wShadowOAMSprite39YCoord], a
ret
LedgeHoppingShadow:
INCBIN "gfx/overworld/shadow.1bpp"
LedgeHoppingShadowEnd:
LedgeHoppingShadowOAM:
dbsprite 9, 11, 0, 0, $ff, 0
dbsprite 10, 11, 0, 0, $ff, OAM_XFLIP
LedgeHoppingShadowOAMEnd:
|
