1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
|
ChampionsRoom_Script:
call EnableAutoTextBoxDrawing
ld hl, ChampionsRoom_ScriptPointers
ld a, [wChampionsRoomCurScript]
call CallFunctionInTable
ret
ResetRivalScript:
xor a ; SCRIPT_CHAMPIONSROOM_DEFAULT
ld [wJoyIgnore], a
ld [wChampionsRoomCurScript], a
ret
ChampionsRoom_ScriptPointers:
def_script_pointers
dw_const ChampionsRoomDefaultScript, SCRIPT_CHAMPIONSROOM_DEFAULT
dw_const ChampionsRoomPlayerEntersScript, SCRIPT_CHAMPIONSROOM_PLAYER_ENTERS
dw_const ChampionsRoomRivalReadyToBattleScript, SCRIPT_CHAMPIONSROOM_RIVAL_READY_TO_BATTLE
dw_const ChampionsRoomRivalDefeatedScript, SCRIPT_CHAMPIONSROOM_RIVAL_DEFEATED
dw_const ChampionsRoomOakArrivesScript, SCRIPT_CHAMPIONSROOM_OAK_ARRIVES
dw_const ChampionsRoomOakCongratulatesPlayerScript, SCRIPT_CHAMPIONSROOM_OAK_CONGRATULATES_PLAYER
dw_const ChampionsRoomOakDisappointedWithRivalScript, SCRIPT_CHAMPIONSROOM_OAK_DISAPPOINTED_WITH_RIVAL
dw_const ChampionsRoomOakComeWithMeScript, SCRIPT_CHAMPIONSROOM_OAK_COME_WITH_ME
dw_const ChampionsRoomOakExitsScript, SCRIPT_CHAMPIONSROOM_OAK_EXITS
dw_const ChampionsRoomPlayerFollowsOakScript, SCRIPT_CHAMPIONSROOM_PLAYER_FOLLOWS_OAK
dw_const ChampionsRoomCleanupScript, SCRIPT_CHAMPIONSROOM_CLEANUP_SCRIPT
ChampionsRoomDefaultScript:
ret
ChampionsRoomPlayerEntersScript:
ld a, PAD_BUTTONS | PAD_CTRL_PAD
ld [wJoyIgnore], a
ld hl, wSimulatedJoypadStatesEnd
ld de, RivalEntrance_RLEMovement
call DecodeRLEList
dec a
ld [wSimulatedJoypadStatesIndex], a
call StartSimulatingJoypadStates
ld a, SCRIPT_CHAMPIONSROOM_RIVAL_READY_TO_BATTLE
ld [wChampionsRoomCurScript], a
ret
RivalEntrance_RLEMovement:
db PAD_UP, 1
db PAD_RIGHT, 1
db PAD_UP, 3
db -1 ; end
ChampionsRoomRivalReadyToBattleScript:
ld a, [wSimulatedJoypadStatesIndex]
and a
ret nz
call Delay3
xor a
ld [wJoyIgnore], a
ld hl, wOptions
res BIT_BATTLE_ANIMATION, [hl]
ld a, TEXT_CHAMPIONSROOM_RIVAL
ldh [hTextID], a
call DisplayTextID
call Delay3
ld hl, wStatusFlags3
set BIT_TALKED_TO_TRAINER, [hl]
set BIT_PRINT_END_BATTLE_TEXT, [hl]
ld hl, RivalDefeatedText
ld de, RivalVictoryText
call SaveEndBattleTextPointers
ld a, OPP_RIVAL3
ld [wCurOpponent], a
; select which team to use during the encounter
ld a, [wRivalStarter]
add $0 ; Wow GameFreak
ld [wTrainerNo], a
xor a
ldh [hJoyHeld], a
ld a, SCRIPT_CHAMPIONSROOM_RIVAL_DEFEATED
ld [wChampionsRoomCurScript], a
ret
ChampionsRoomRivalDefeatedScript:
ld a, [wIsInBattle]
cp $ff
jp z, ResetRivalScript
call UpdateSprites
SetEvent EVENT_BEAT_CHAMPION_RIVAL
ld a, PAD_CTRL_PAD
ld [wJoyIgnore], a
ld a, TEXT_CHAMPIONSROOM_RIVAL
ldh [hTextID], a
call ChampionsRoom_DisplayTextID_AllowABSelectStart
ld a, CHAMPIONSROOM_RIVAL
ldh [hSpriteIndex], a
call SetSpriteMovementBytesToFF
ld a, SCRIPT_CHAMPIONSROOM_OAK_ARRIVES
ld [wChampionsRoomCurScript], a
ret
ChampionsRoomOakArrivesScript:
farcall Music_Cities1AlternateTempo
ld a, TEXT_CHAMPIONSROOM_OAK
ldh [hTextID], a
call ChampionsRoom_DisplayTextID_AllowABSelectStart
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
call SetSpriteMovementBytesToFF
ld de, OakEntranceAfterVictoryMovement
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
call MoveSprite
ld a, TOGGLE_CHAMPIONS_ROOM_OAK
ld [wToggleableObjectIndex], a
predef ShowObject
ld a, SCRIPT_CHAMPIONSROOM_OAK_CONGRATULATES_PLAYER
ld [wChampionsRoomCurScript], a
ret
OakEntranceAfterVictoryMovement:
db NPC_MOVEMENT_UP
db NPC_MOVEMENT_UP
db NPC_MOVEMENT_UP
db NPC_MOVEMENT_UP
db NPC_MOVEMENT_UP
db -1 ; end
ChampionsRoomOakCongratulatesPlayerScript:
ld a, [wStatusFlags5]
bit BIT_SCRIPTED_NPC_MOVEMENT, a
ret nz
ld a, PLAYER_DIR_LEFT
ld [wPlayerMovingDirection], a
ld a, CHAMPIONSROOM_RIVAL
ldh [hSpriteIndex], a
ld a, SPRITE_FACING_LEFT
ldh [hSpriteFacingDirection], a
call SetSpriteFacingDirectionAndDelay
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
xor a ; SPRITE_FACING_DOWN
ldh [hSpriteFacingDirection], a
call SetSpriteFacingDirectionAndDelay
ld a, TEXT_CHAMPIONSROOM_OAK_CONGRATULATES_PLAYER
ldh [hTextID], a
call ChampionsRoom_DisplayTextID_AllowABSelectStart
ld a, SCRIPT_CHAMPIONSROOM_OAK_DISAPPOINTED_WITH_RIVAL
ld [wChampionsRoomCurScript], a
ret
ChampionsRoomOakDisappointedWithRivalScript:
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
ld a, SPRITE_FACING_RIGHT
ldh [hSpriteFacingDirection], a
call SetSpriteFacingDirectionAndDelay
ld a, TEXT_CHAMPIONSROOM_OAK_DISAPPOINTED_WITH_RIVAL
ldh [hTextID], a
call ChampionsRoom_DisplayTextID_AllowABSelectStart
ld a, SCRIPT_CHAMPIONSROOM_OAK_COME_WITH_ME
ld [wChampionsRoomCurScript], a
ret
ChampionsRoomOakComeWithMeScript:
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
xor a ; SPRITE_FACING_DOWN
ldh [hSpriteFacingDirection], a
call SetSpriteFacingDirectionAndDelay
ld a, TEXT_CHAMPIONSROOM_OAK_COME_WITH_ME
ldh [hTextID], a
call ChampionsRoom_DisplayTextID_AllowABSelectStart
ld de, OakExitChampionsRoomMovement
ld a, CHAMPIONSROOM_OAK
ldh [hSpriteIndex], a
call MoveSprite
ld a, SCRIPT_CHAMPIONSROOM_OAK_EXITS
ld [wChampionsRoomCurScript], a
ret
OakExitChampionsRoomMovement:
db NPC_MOVEMENT_UP
db NPC_MOVEMENT_UP
db -1 ; end
ChampionsRoomOakExitsScript:
ld a, [wStatusFlags5]
bit BIT_SCRIPTED_NPC_MOVEMENT, a
ret nz
ld a, TOGGLE_CHAMPIONS_ROOM_OAK
ld [wToggleableObjectIndex], a
predef HideObject
ld a, SCRIPT_CHAMPIONSROOM_PLAYER_FOLLOWS_OAK
ld [wChampionsRoomCurScript], a
ret
ChampionsRoomPlayerFollowsOakScript:
ld a, PAD_BUTTONS | PAD_CTRL_PAD
ld [wJoyIgnore], a
ld hl, wSimulatedJoypadStatesEnd
ld de, WalkToHallOfFame_RLEMovement
call DecodeRLEList
dec a
ld [wSimulatedJoypadStatesIndex], a
call StartSimulatingJoypadStates
ld a, SCRIPT_CHAMPIONSROOM_CLEANUP_SCRIPT
ld [wChampionsRoomCurScript], a
ret
WalkToHallOfFame_RLEMovement:
db PAD_UP, 4
db PAD_LEFT, 1
db -1 ; end
ChampionsRoomCleanupScript:
ld a, [wSimulatedJoypadStatesIndex]
and a
ret nz
xor a
ld [wJoyIgnore], a
ld a, SCRIPT_CHAMPIONSROOM_DEFAULT
ld [wChampionsRoomCurScript], a
ret
ChampionsRoom_DisplayTextID_AllowABSelectStart:
ld a, PAD_CTRL_PAD
ld [wJoyIgnore], a
call DisplayTextID
ld a, PAD_BUTTONS | PAD_CTRL_PAD
ld [wJoyIgnore], a
ret
ChampionsRoom_TextPointers:
def_text_pointers
dw_const ChampionsRoomRivalText, TEXT_CHAMPIONSROOM_RIVAL
dw_const ChampionsRoomOakText, TEXT_CHAMPIONSROOM_OAK
dw_const ChampionsRoomOakCongratulatesPlayerText, TEXT_CHAMPIONSROOM_OAK_CONGRATULATES_PLAYER
dw_const ChampionsRoomOakDisappointedWithRivalText, TEXT_CHAMPIONSROOM_OAK_DISAPPOINTED_WITH_RIVAL
dw_const ChampionsRoomOakComeWithMeText, TEXT_CHAMPIONSROOM_OAK_COME_WITH_ME
ChampionsRoomRivalText:
text_asm
CheckEvent EVENT_BEAT_CHAMPION_RIVAL
ld hl, .IntroText
jr z, .printText
ld hl, ChampionsRoomRivalAfterBattleText
.printText
call PrintText
jp TextScriptEnd
.IntroText:
text_far _ChampionsRoomRivalIntroText
text_end
RivalDefeatedText:
text_far _RivalDefeatedText
text_end
RivalVictoryText:
text_far _RivalVictoryText
text_end
ChampionsRoomRivalAfterBattleText:
text_far _ChampionsRoomRivalAfterBattleText
text_end
ChampionsRoomOakText:
text_far _ChampionsRoomOakText
text_end
ChampionsRoomOakCongratulatesPlayerText:
text_asm
ld a, [wPlayerStarter]
ld [wNamedObjectIndex], a
call GetMonName
ld hl, .Text
call PrintText
jp TextScriptEnd
.Text:
text_far _ChampionsRoomOakCongratulatesPlayerText
text_end
ChampionsRoomOakDisappointedWithRivalText:
text_far _ChampionsRoomOakDisappointedWithRivalText
text_end
ChampionsRoomOakComeWithMeText:
text_far _ChampionsRoomOakComeWithMeText
text_end
|
