1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
|
VermilionCity_Script:
call EnableAutoTextBoxDrawing
ld hl, wPikachuMapScriptFlags
res BIT_PIKACHU_MAP_SCRIPT_ACTIVE, [hl]
ld hl, wCurrentMapScriptFlags
bit BIT_CUR_MAP_LOADED_2, [hl]
res BIT_CUR_MAP_LOADED_2, [hl]
push hl
call nz, VermilionCityLeftSSAnneCallbackScript
pop hl
bit BIT_CUR_MAP_LOADED_1, [hl]
res BIT_CUR_MAP_LOADED_1, [hl]
call nz, .setFirstLockTrashCanIndex
ld hl, VermilionCity_ScriptPointers
ld a, [wVermilionCityCurScript]
call CallFunctionInTable
call .vermilionCityScript_19869
ret
.vermilionCityScript_19869
CheckEventHL EVENT_LEFT_FANCLUB_AFTER_BIKE_VOUCHER
ret nz
CheckEventReuseHL EVENT_GOT_BIKE_VOUCHER
ret z
SetEventReuseHL EVENT_LEFT_FANCLUB_AFTER_BIKE_VOUCHER
ret
.setFirstLockTrashCanIndex
call Random
ldh a, [hRandomAdd]
ld b, a
ldh a, [hRandomSub]
adc b
and $e
ld [wFirstLockTrashCanIndex], a
ret
VermilionCityLeftSSAnneCallbackScript:
CheckEventHL EVENT_SS_ANNE_LEFT
ret z
CheckEventReuseHL EVENT_WALKED_PAST_GUARD_AFTER_SS_ANNE_LEFT
SetEventReuseHL EVENT_WALKED_PAST_GUARD_AFTER_SS_ANNE_LEFT
ret nz
ld a, SCRIPT_VERMILIONCITY_PLAYER_EXIT_SHIP
ld [wVermilionCityCurScript], a
ret
VermilionCity_ScriptPointers:
def_script_pointers
dw_const VermilionCityDefaultScript, SCRIPT_VERMILIONCITY_DEFAULT
dw_const VermilionCityPlayerMovingUp1Script, SCRIPT_VERMILIONCITY_PLAYER_MOVING_UP1
dw_const VermilionCityPlayerExitShipScript, SCRIPT_VERMILIONCITY_PLAYER_EXIT_SHIP
dw_const VermilionCityPlayerMovingUp2Script, SCRIPT_VERMILIONCITY_PLAYER_MOVING_UP2
dw_const VermilionCityPlayerAllowedToPassScript, SCRIPT_VERMILIONCITY_PLAYER_ALLOWED_TO_PASS
VermilionCityDefaultScript:
ld a, [wSpritePlayerStateData1FacingDirection]
and a ; cp SPRITE_FACING_DOWN
jr nz, .return
ld hl, SSAnneTicketCheckCoords
call ArePlayerCoordsInArray
jr nc, .return
xor a
ldh [hJoyHeld], a
ld [wSavedCoordIndex], a ; unnecessary
ld a, TEXT_VERMILIONCITY_SAILOR1
ldh [hTextID], a
call DisplayTextID
CheckEvent EVENT_SS_ANNE_LEFT
jr nz, .ship_departed
ld b, S_S_TICKET
predef GetQuantityOfItemInBag
ld a, b
and a
ret nz
.ship_departed
ld a, PAD_UP
ld [wSimulatedJoypadStatesEnd], a
ld a, $1
ld [wSimulatedJoypadStatesIndex], a
call StartSimulatingJoypadStates
ld a, SCRIPT_VERMILIONCITY_PLAYER_MOVING_UP1
ld [wVermilionCityCurScript], a
ret
.return
ret
SSAnneTicketCheckCoords:
dbmapcoord 18, 30
db -1 ; end
VermilionCityPlayerAllowedToPassScript:
ld hl, SSAnneTicketCheckCoords
call ArePlayerCoordsInArray
ret c
ld a, SCRIPT_VERMILIONCITY_DEFAULT
ld [wVermilionCityCurScript], a
ret
VermilionCityPlayerExitShipScript:
ld a, PAD_BUTTONS | PAD_CTRL_PAD
ld [wJoyIgnore], a
ld a, PAD_UP
ld [wSimulatedJoypadStatesEnd], a
ld [wSimulatedJoypadStatesEnd + 1], a
ld a, 2
ld [wSimulatedJoypadStatesIndex], a
call StartSimulatingJoypadStates
ld a, SCRIPT_VERMILIONCITY_PLAYER_MOVING_UP2
ld [wVermilionCityCurScript], a
ret
VermilionCityPlayerMovingUp2Script:
ld a, [wSimulatedJoypadStatesIndex]
and a
ret nz
xor a
ld [wJoyIgnore], a
ldh [hJoyHeld], a
ld a, SCRIPT_VERMILIONCITY_DEFAULT
ld [wVermilionCityCurScript], a
ret
VermilionCityPlayerMovingUp1Script:
ld a, [wSimulatedJoypadStatesIndex]
and a
ret nz
ld c, 10
call DelayFrames
ld a, SCRIPT_VERMILIONCITY_DEFAULT
ld [wVermilionCityCurScript], a
ret
VermilionCity_TextPointers:
def_text_pointers
dw_const VermilionCityBeautyText, TEXT_VERMILIONCITY_BEAUTY
dw_const VermilionCityGambler1Text, TEXT_VERMILIONCITY_GAMBLER1
dw_const VermilionCitySailor1Text, TEXT_VERMILIONCITY_SAILOR1
dw_const VermilionCityGambler2Text, TEXT_VERMILIONCITY_GAMBLER2
dw_const VermilionCityMachopText, TEXT_VERMILIONCITY_MACHOP
dw_const VermilionCitySailor2Text, TEXT_VERMILIONCITY_SAILOR2
dw_const VermilionCityOfficerJennyText, TEXT_VERMILIONCITY_OFFICER_JENNY
dw_const VermilionCitySignText, TEXT_VERMILIONCITY_SIGN
dw_const VermilionCityNoticeSignText, TEXT_VERMILIONCITY_NOTICE_SIGN
dw_const MartSignText, TEXT_VERMILIONCITY_MART_SIGN
dw_const PokeCenterSignText, TEXT_VERMILIONCITY_POKECENTER_SIGN
dw_const VermilionCityPokemonFanClubSignText, TEXT_VERMILIONCITY_POKEMON_FAN_CLUB_SIGN
dw_const VermilionCityGymSignText, TEXT_VERMILIONCITY_GYM_SIGN
dw_const VermilionCityHarborSignText, TEXT_VERMILIONCITY_HARBOR_SIGN
VermilionCityBeautyText:
text_far _VermilionCityBeautyText
text_end
VermilionCityGambler1Text:
text_asm
CheckEvent EVENT_SS_ANNE_LEFT
jr nz, .ship_departed
ld hl, .DidYouSeeText
call PrintText
jr .text_script_end
.ship_departed
ld hl, .SSAnneDepartedText
call PrintText
.text_script_end
jp TextScriptEnd
.DidYouSeeText:
text_far _VermilionCityGambler1DidYouSeeText
text_end
.SSAnneDepartedText:
text_far _VermilionCityGambler1SSAnneDepartedText
text_end
VermilionCitySailor1Text:
text_asm
CheckEvent EVENT_SS_ANNE_LEFT
jr nz, .ship_departed
ld a, [wSpritePlayerStateData1FacingDirection]
cp SPRITE_FACING_RIGHT
jr z, .greet_player
ld hl, .inFrontOfOrBehindGuardCoords
call ArePlayerCoordsInArray
jr nc, .greet_player_and_check_ticket
.greet_player
ld hl, .WelcomeToSSAnneText
call PrintText
jr .end
.greet_player_and_check_ticket
ld hl, .DoYouHaveATicketText
call PrintText
ld b, S_S_TICKET
predef GetQuantityOfItemInBag
ld a, b
and a
jr nz, .player_has_ticket
ld hl, .YouNeedATicketText
call PrintText
jr .end
.player_has_ticket
ld hl, .FlashedTicketText
call PrintText
ld a, SCRIPT_VERMILIONCITY_PLAYER_ALLOWED_TO_PASS
ld [wVermilionCityCurScript], a
jr .end
.ship_departed
ld hl, .ShipSetSailText
call PrintText
.end
jp TextScriptEnd
.inFrontOfOrBehindGuardCoords
dbmapcoord 19, 29 ; in front of guard
dbmapcoord 19, 31 ; behind guard
db -1 ; end
.WelcomeToSSAnneText:
text_far _VermilionCitySailor1WelcomeToSSAnneText
text_end
.DoYouHaveATicketText:
text_far _VermilionCitySailor1DoYouHaveATicketText
text_end
.FlashedTicketText:
text_far _VermilionCitySailor1FlashedTicketText
text_end
.YouNeedATicketText:
text_far _VermilionCitySailor1YouNeedATicketText
text_end
.ShipSetSailText:
text_far _VermilionCitySailor1ShipSetSailText
text_end
VermilionCityGambler2Text:
text_far _VermilionCityGambler2Text
text_end
VermilionCityMachopText:
text_far _VermilionCityMachopText
text_asm
ld a, MACHOP
call PlayCry
call WaitForSoundToFinish
ld hl, .StompingTheLandFlatText
ret
.StompingTheLandFlatText:
text_far _VermilionCityMachopStompingTheLandFlatText
text_end
VermilionCitySailor2Text:
text_far _VermilionCitySailor2Text
text_end
VermilionCitySignText:
text_asm
farcall VermilionCityPrintSignText
jp TextScriptEnd
VermilionCityNoticeSignText:
text_asm
farcall VermilionCityPrintNoticeSignText
jp TextScriptEnd
VermilionCityPokemonFanClubSignText:
text_asm
farcall VermilionCityPrintPokemonFanClubSignText
jp TextScriptEnd
VermilionCityGymSignText:
text_asm
farcall VermilionCityPrintGymSignText
jp TextScriptEnd
VermilionCityHarborSignText:
text_asm
farcall VermilionCityPrintHarborSignText
jp TextScriptEnd
VermilionCityOfficerJennyText:
text_asm
farcall VermilionCityPrintOfficerJennyText
jp TextScriptEnd
|
